'DMS20B.dmc - 08-30-11

#AUTO

JS#DMSINIT

JP#DMSMAIN

EN

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*INITIALIZE

#DMSINIT

MG"INITIALIZING..."

' SET ANALOG INPUTS TO +/-5V

AQ0,1;AQ1,1;AQ2,1;AQ3,1

AQ4,1;AQ5,1;AQ6,1;AQ7,1

' SET ANALOG OUTPUT TO +/-5V

DQ0,3

OP$00; 'TURN OFF GREEN LEDS

CB10;CB12;CB14;'TURN OFF ALARM LEDS

'\*\*\*\*THESE ARE CONTROL VARIABLES

CYCL=2500; 'CYCLE TIME: 1000 = 1 SEC

MG"CYCLE TIME = ",(CYCL/1000){F1.1},`

" SEC."

' LETS HOW LONG BEFORE MOVING ON TO

' NEXT CHANNEL - REMEMBER, PANEL

' METER TAKES TIME TO READ ITS INPUT

WARM=0.10; '10 C THRESHOLD FOR WARMING

MG"WARM UP = ",(WARM\*100){F1.1},`

" DEGREES C"

BNTIME=3000; 'HOW LONG RESET BUTTON

'NEEDS TO BE HELD FOR FULL RESET

MG"RESET TIME = ",(BNTIME/1000){F1.1},`

" SEC."

'

ALRMFLG=$00;RSFLG=$00;CHFLG=$00

TEMPPTR=0; 'GLOBAL USED TO POINT AT

GTEMP=0; ' GLOBAL RETURNED TEMPERATURE

HOT=9.9999;'USED AS INIT COLD POINT

'SETUP TEMPERATURE ARRAY...........

HXSIZE=8;HYSIZE=7;HSIZE=HXSIZE\*HYSIZE

DM HIST[HSIZE]

'SETUP PARAMETER ARRAY

PSIZE=HXSIZE\*5

DM PARAM[PSIZE]

' OFFSET POINTERS INTO PARAM ARRAY

ACTV=0; 'ACTIVE CHANNELS

OFFSET=1

SLOPE=2

'EMPIRICAL OFFSETS

PARAM[8]=.8393;PARAM[9]=.8535

PARAM[10]=.8447;PARAM[11]=.8684

PARAM[12]=.8588;PARAM[13]=.8584

PARAM[14]=.8496;PARAM[15]=.8732

'CALCULATED SLOPES

PARAM[16]=.5798;PARAM[17]=.5659

PARAM[18]=.5798;PARAM[19]=.5659

PARAM[20]=.5798;PARAM[21]=.5659

PARAM[22]=.5798;PARAM[23]=.5659

' BIT MASK ARRAY

DM BMASK[8]

'GENERAL BITMASK VALUES

BMASK[0]=$01;BMASK[1]=$02;BMASK[2]=$04

BMASK[3]=$08;BMASK[4]=$10;BMASK[5]=$20

BMASK[6]=$40;BMASK[7]=$080

DM CMASK[8]

CMASK[0]=$FE;CMASK[1]=$FD;CMASK[2]=$FB

CMASK[3]=$F7;CMASK[4]=$EF;CMASK[5]=$DF

CMASK[6]=$BF;CMASK[7]=$7F

DM FLSHR[8]

FLSHR[0]=1;FLSHR[1]=1;FLSHR[2]=1

FLSHR[3]=1;FLSHR[4]=1;FLSHR[5]=1

FLSHR[6]=1;FLSHR[7]=1

' SETUP EMAIL FOR ALARM NOTIFICATIONS

MA128,114,23,233

MD barry@ucolick.org

MS dewar-monitor-no-reply@ucolick.org

II1,1,12

II2,0,11

XQ#IMALIVE,1

XQ#FLASH,2

T1=TIME;MAINCT=0

JS#CKCONNS

JS#SETARY;JS#SETARY

EN

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*FILL HISTORY ARRAY

#SETARY

CTI=0;CTJ=0

#ZEROAVG

HISTPTR=CTI+CTJ

IF (CTI<HXSIZE);HIST[HISTPTR]=HOT

ELSE;HIST[HISTPTR]=0

ENDIF

CTJ=CTJ+1

JP#ZEROAVG,CTJ<HXSIZE

CTI=HYSIZE-2;CTI=HYSIZE-CTI

#ILOOP

CTJ=0

#JLOOP

HISTPTR=(CTI\*HXSIZE)+CTJ

IF PARAM[CTJ] = 1

 TEMPPTR=CTJ

 JS#CVTEMP

 HIST[HISTPTR]=GTEMP

 CHAN=CTJ

 JS#AVGCHAN

ELSE

 HIST[HISTPTR]=0

ENDIF

WT 4

CTJ=CTJ+1

JP#JLOOP, CTJ<=7

CTI=CTI+1

JP#ILOOP,CTI<=HYSIZE-1

QU HIST[],0,HSIZE-1,1

EN

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*MAIN

#DMSMAIN

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*MAIN

MG"MAIN..."

#DMSLOOP

JS#CKCONNS

JS#CKTEMPS

WT 100

MAINCT=MAINCT+1

JP#DMSLOOP

EN

'\*\*\*\*\*\*\*\*\*\*CHECK FOR CONNECTED CHANNELS

#CKCONNS

CT=0

#CKLOOP

PARAM[CT]=0

IF @IN[CT] = 0

 PARAM[CT]=1

ENDIF

CT=CT+1

JP#CKLOOP,CT<8

EN

'\*\*\*\*\*\*\*\*\*\*\*CHECK INCOMING TEMPERATURES

#CKTEMPS

CHAN=0

#TLOOP

 LPTIME=TIME

 PARAM[CHAN] = 1

 SBCHAN; 'TURN ON CHANNEL LED

 CTI=HYSIZE-2

 #ADJ

 OLDPTR=(CTI\*HXSIZE)+CHAN

 NEWPTR=OLDPTR+HXSIZE

 SWAP=HIST[OLDPTR]

 HIST[NEWPTR]=SWAP

 CTI=CTI-1

 JP#ADJ,CTI>1

 HISTPTR=(2\*HXSIZE)+CHAN

 TEMPPTR=CHAN

 JS#CVTEMP

 HIST[HISTPTR]=GTEMP

 JS#DISPTMP

 #WTMORE

 LPNOW=TIME;'FINISH 2 SEC DELAY

 #WT4RS

 JP#WT4RS,RSFLG<>$00

 JP#WTMORE,LPNOW<(LPTIME+2000)

 JS#AVGCHAN; 'RESET CHANNEL AVERAGE

 JS#CKWARM; 'IS IT TOO HOT?

 CBCHAN; 'TURN OFF CHANNEL LED

ENDIF

CHAN=CHAN+1

JP#TLOOP,CHAN<HXSIZE

MG"LOOP:",MAINCT{Z10.0}{N}

MG" ALRMFLG = ",ALRMFLG{$3.0}

EN

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*CALC AVERAGE

#AVGCHAN

AVGCT=2;AVG1=0

' LOOP THRU LAST n TEMPERATURES

#AVLOOP

PPOOP=(AVGCT\*HXSIZE)+CHAN

HISTPTR=(AVGCT\*HXSIZE)+CHAN

AVG1=AVG1+HIST[HISTPTR]

AVGCT=AVGCT+1

JP#AVLOOP,AVGCT<HYSIZE

AVG2=AVG1/(HYSIZE-2)

HISTPTR=HXSIZE+CHAN

HIST[HISTPTR]=AVG2

IF(AVG2<HIST[CHAN]

 HIST[CHAN]=AVG2

ENDIF

EN

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*CONVERT TEMERATURE

#CVTEMP

GTEMP=@AN[TEMPPTR]

OFFPTR=(OFFSET\*HXSIZE)+TEMPPTR

SLPPTR=(SLOPE\*HXSIZE)+TEMPPTR

TOFFSET=PARAM[OFFPTR]

TSLOPE=PARAM[SLPPTR]

IF(GTEMP>=TOFFSET)

 GTEMP=@ABS[(GTEMP-TOFFSET)/TSLOPE]

 GTEMP= GTEMP\*-1

ELSE

 GTEMP=@ABS[(TOFFSET-GTEMP)/TSLOPE]

ENDIF

EN

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*CHECK FOR WARMING

#CKWARM

COLDPTR=TEMPPTR;AVPTR=(TEMPPTR+HXSIZE)

ACOLD=HIST[COLDPTR];AAVG=HIST[AVPTR]

If(AAVG>(ACOLD+WARM))

 MG"\*\*CHANNEL ",COLDPTR{F1.0}{N}

 MG" IS TOO HOT!"

 MG"AVERAGE: ",AAVG," COLDEST: ",ACOLD

 IF((ALRMFLG&BMASK[COLDPTR])=0)

 ALRMFLG=ALRMFLG|BMASK[COLDPTR]

 MG"++++++++++++++++++ALARM! CH:"{N}

 MG COLDPTR{F1.0}

 JS#JLIST+COLDPTR+1

 ENDIF

 SB9; 'TURN ON SONALERT

ENDIF

EN

'JUMPLIST FOR SENDING EMAIL MESSAGE

#JLIST

MG"DEWAR OVER-TEMP ALARM! CH:0"{M};EN

MG"DEWAR OVER-TEMP ALARM! CH:1"{M};EN

MG"DEWAR OVER-TEMP ALARM! CH:2"{M};EN

MG"DEWAR OVER-TEMP ALARM! CH:3"{M};EN

MG"DEWAR OVER-TEMP ALARM! CH:4"{M};EN

MG"DEWAR OVER-TEMP ALARM! CH:5"{M};EN

MG"DEWAR OVER-TEMP ALARM! CH:6"{M};EN

MG"DEWAR OVER-TEMP ALARM! CH:7"{M};EN

EN

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*DISPLAY TEMPERATURE

#DISPTMP

'LIMIT TO ANALOG OUTPUT RANGE

IF(GTEMP>5.0);GTEMP=5.0;ENDIF

IF(GTEMP<-5.0);GTEMP=5.0;ENDIF

AO 0,GTEMP

EN

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*RESET INTERRUPT

#ININT1

'MG"INTERRUPT 1!... RESET"

INTIME=TIME

RSFLG=ALRMFLG;'SIGNAL TO MAIN PROGRAM

OP$FF; 'TURN ON GREEN LEDS

SB10;SB12;SB14; 'TURN ON ALARM LEDS

#CLR0

JP#CLR0,@IN[12]=1; 'WAIT TIL RELEASED

IF(ALRMFLG = 0)

 WT10;OP$00; 'TURN OFF GREEN LEDS

 CB10;CB12;CB14;'TURN OFF ALARM LEDS

 RI; 'LEAVE, NO ALARMS SET

ENDIF

' CHECK TO SEE IF BUTTON HELD

' MORE THAN 4 SECONDS

OUTTIME=TIME

IF(OUTTIME>(INTIME+BNTIME)

 JS#SETARY

 RSFLG=$00;'CLEAR SIGNAL

 ALRMFLG=$00;'CLEAR ALARMS

 JP#RSOUT

ENDIF

'FILL ARRAY FOR SELECTED CHANNEL

SELCH=\_TI1 & $07

SELCH=7-SELCH; 'PADDLE SW NUMBER

OLDPTR=TEMPPTR; 'SAVE FOR NOW

OLDTEMP=GTEMP; 'SAVE FOR NOW

'CHECK FOR ALARM CHANNELS

IF(ALRMFLG&BMASK[SELCH]>0)

 FILLCT=1; 'OVERWRITE AVERAGE TOO

 TEMPPTR= SELCH

 GTEMP=@AN[TEMPPTR]

 JS#CVTEMP

'SHOVE INTO ALL TEMPS FOR THIS CHAN

 #REFILL

 FILLPTR=(HXSIZE\*FILLCT)+ SELCH

 HIST[FILLPTR]=GTEMP

 FILLCT=FILLCT+1

 JP#REFILL,FILLCT<HYSIZE

'RESET COLDEST VALUE

 FILLPTR=SELCH;HIST[FILLPTR]=9.9999

'CLEAR ONLY [SELCH] BIT

MG"ALRMFLG = ",ALRMFLG{$2.0}

ALRMFLG=ALRMFLG&CMASK[SELCH]

MG"ALRMFLG = ",ALRMFLG{$2.0}

ENDIF

#RSOUT

WT10;OP$00; 'TURN OFF GREEN LEDS

CB10;CB12;CB14;'TURN OFF ALARM LEDS

’ALRMFLG=$000; 'CLEAR ALARM

RSFLG=$00; 'CLEAR RESET FLAG

QU HIST[],0,HSIZE-1,1

TEMPPTR=OLDPTR; 'RESTORE

GTEMP=OLDTEMP

CB9; 'TURN OFF SONALERT

RI

'\*\*\*\*\*\*\*\*\*SHOW SINGLE CHANNEL INTERRUPT

#ININT2

'MG"INTERRUPT 2!...SHOW SINGLE TEMP"

CB CHAN

#CLR2

SHOWCH=\_TI1 & $07;SHOWCH=7-SHOWCH

IF(PARAM[SHOWCH]=0);

 AO 0,1.999; 'DISPLAY A ZERO

 #BADCHAN

 MG"CAN'T SHOW UNCONNECTED CHANNEL"

 JP#BADCHAN,@IN[11]=1

 WT20;RI

ENDIF

SB SHOWCH;TEMPPTR=SHOWCH

JS#CVTEMP

JS#DISPTMP

WT20;CB SHOWCH

JP#CLR2,@IN[11]=1

SB CHAN;WT10

RI

EN

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*I'M ALIVE THREAD

#IMALIVE

ITSME=1

#IALOOP

IF ITSME=1

 SB8

ELSE

 CB8

ENDIF

WT 700;ITSME=ITSME\*-1

JP #IALOOP

EN

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*FLASH GREEN LED THREAD

#FLASH

JP#FLASH,ALRMFLG=0

FCT=0

#FLOOP

IF(ALRMFLG&BMASK[FCT])

 FLSHR[FCT]=FLSHR[FCT]\*-1

 IF(FLSHR[FCT]>0);SBFCT;WT25

 ELSE;CBFCT;WT10

 ENDIF

ENDIF

FCT=FCT+1

JP#FLOOP,FCT<8

JP#FLASH

EN

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\* COMMAND ERROR ROUTINE

#CMDERR

MG"An error occurred at line",\_ED

TC1;ZS

OP$FF; 'TURN ON GREEN LEDS

HX1; 'STOP I'M ALIVE THREAD

HX2; 'STOP FLASH THREAD

EN